شبیه سازی پارامتردهی یک MOSFET مبتنی بر جدول داده از SPICE matlab

این مثال نشان می‌دهد که چگونه می‌توان از نتایج شبیه‌سازی SPICE یک ترانزیستور اثر میدان فلز-اکسید-نیمه‌رسانا (MOSFET) برای تعیین مقادیر پارامترهای یک MOSFET کانال-N (مبتنی بر جدول داده) در Simscape™ استفاده کرد. سپس، ویژگی‌های MOSFET کانال-N در Simscape با نتایج شبیه‌سازی نت‌لیست SPICE مقایسه می‌شود.

باز کردن مدل MOSFET کانال-N (مبتنی بر جدول داده)

باز کردن زیرمدار MOSFET

زیرمدار شامل مدل SPICE یک ترانزیستور قدرت کانال-N است. برای باز کردن آن، در پنجره دستور MATLAB، این دستور را وارد کنید:
edit IAUC100N04S6L014.cir

ایجاد یک نت‌لیست مشخصه انتقالی

می‌توانید یک نت‌لیست SPICE ایجاد کنید که دامنه کاری هدف را برای زیرمدار مشخص کند. نت‌لیست IAUC100N04S6L014_idvgs.net مشخصه‌های انتقالی را با فهرستی از ولتاژهای درین-سورس شبیه‌سازی می‌کند.

* مشخصه انتقالی MOSFET مدل IAUC100N04S6L014  
.opt DampInductors=0 Thev_Induc=1 Gfarad=0 Gfloat=0 reltol=1e-05 abstol=1e-05 vntol=1e-05 Gmin=0 cshunt=0 cshuntintern=0 gshunt=0 topologycheck=0

X1 dut1 dut2 dut3 dut4 dut5 IAUC100N04S6L014  
V1 dut1 0 2  
V2 dut2 0 pwl(0 0 20 4.5)  
V3 dut3 0 0  
V4 dut4 0 27  
.step V1 list 2 5 8 11 14  
.tran 1m 20  
.lib IAUC100N04S6L014.cir  
.end

تنظیم پارامترهای جدول داده برای مشخصه انتقالی

برای به‌دست آوردن مشخصه‌های انتقالی موردنیاز MOSFET، شبیه‌سازی را در SPICE اجرا کنید. اسکریپت TabulatedMOSFETSetParameters از نتایج ذخیره‌شده در فایل خام IAUC100N04S6L014_idvgs1.raw برای تعیین مقادیر پارامتر MOSFET کانال-N (مبتنی بر جدول داده) استفاده می‌کند. برای تنظیم پارامترهای کانال MOSFET، در تب Define Condition، گزینه Set MOSFET channel parameters را علامت بزنید، یا از تابع set_param استفاده کنید.

مقایسه مشخصه انتقالی

نمودار زیر، مشخصه‌های انتقالی MOSFET کانال-N (مبتنی بر جدول داده) را با نتایج شبیه‌سازی زیرمدار SPICE مقایسه می‌کند.

ایجاد نت‌لیست مشخصه خروجی

برای پارامتردهی یک MOSFET کانال-N (مبتنی بر جدول داده)، می‌توان از داده‌های مشخصه خروجی SPICE نیز استفاده کرد. نت‌لیست IAUC100N04S6L014_idvds.net مشخصه‌های خروجی را با فهرستی از ولتاژهای گیت-سورس شبیه‌سازی می‌کند.

* مشخصه خروجی MOSFET مدل IAUC100N04S6L014  
.opt DampInductors=0 Thev_Induc=1 Gfarad=0 Gfloat=0 reltol=1e-05 abstol=1e-05 vntol=1e-05 Gmin=0 cshunt=0 cshuntintern=0 gshunt=0 topologycheck=0

X1 dut1 dut2 dut3 dut4 dut5 IAUC100N04S6L014  
V1 dut1 0 pwl(0 0 20 15)  
V2 dut2 0 2  
V3 dut3 0 0  
V4 dut4 0 27  
.step V2 1 4 0.5  
.tran 2m 20  
.lib IAUC100N04S6L014.cir  
.end

تنظیم پارامترهای جدول داده برای مشخصه خروجی

فایل خام IAUC100N04S6L014_idvds1.raw شامل نتایج مشخصه خروجی شبیه‌سازی‌شده در SPICE است. برای تغییر مسیر فایل خام و نوع نمودار، پارامترهای مربوطه را در تب Define Condition مشخص کنید یا از تابع set_param استفاده نمایید.

مقایسه مشخصه خروجی

نمودار زیر مشخصه خروجی MOSFET کانال-N (مبتنی بر جدول داده) را با نتایج شبیه‌سازی زیرمدار SPICE مقایسه می‌کند.

ایجاد نت‌لیست ظرفیت خازنی نسبت به ولتاژ درین-سورس

برای پارامتردهی ظرفیت خازنی جدول‌دار MOSFET کانال-N، نت‌لیست SPICE ایجاد کنید که ظرفیت ورودی (Ciss)، ظرفیت انتقال معکوس (Crss)، و ظرفیت خروجی (Coss) را نسبت به ولتاژ درین-سورس با ولتاژ گیت-سورس خاص شبیه‌سازی می‌کند. نت‌لیست IAUC100N04S6L014_cvds.net نتایج I-V ظرفیت‌های Ciss و Crss را با یک سیگنال AC کوچک روی ولتاژ گیت-سورس و نتایج I-V ظرفیت Coss را با یک سیگنال AC کوچک روی ولتاژ درین-سورس شبیه‌سازی می‌کند.

* اندازه‌گیری Ciss، Crss، Coss برای MOSFET مدل IAUC100N04S6L014  
.opt DampInductors=0 Thev_Induc=1 Gfarad=0 Gfloat=0 reltol=1e-05 abstol=1e-05 vntol=1e-05 Gmin=0 cshunt=0 cshuntintern=0 gshunt=0 topologycheck=0

* Ciss، Crss با AC کوچک روی Vgs  
X1 dut11 dut12 dut13 dut14 dut15 iauc100n04s6l014  
V11 dut11 0 sine({VDC} 0 1e6)  
V12 dut12 0 sine(0 0.05 1e6)  
V13 dut13 0 0  
V14 dut14 0 27  

* Coss با AC کوچک روی Vds  
X2 dut21 dut22 dut23 dut24 dut25 iauc100n04s6l014  
V21 dut21 0 sine({VDC} 0.05 1e6)  
V22 dut22 0 sine(0 0 1e6)  
V23 dut23 0 0  
V24 dut24 0 27  
*.param VDC = 0  
.step param VDC 0 30 1  
.tran 1e-7 5e-6 0 2e-8  
.inc IAUC100N04S6L014.cir  
.end

تنظیم پارامترهای جدول داده برای ظرفیت خازنی

فایل خام IAUC100N04S6L014_cvds1.raw نتایج I-V ظرفیت خازنی شبیه‌سازی‌شده در SPICE را ذخیره می‌کند. برای تنظیم پارامترهای ظرفیت خازنی MOSFET، در تب Define Conditions، گزینه Set MOSFET capacitance parameters را علامت بزنید یا از تابع set_param استفاده نمایید.

مقایسه ظرفیت Ciss، Crss و Coss

نمودار زیر ظرفیت‌های Ciss، Crss و Coss MOSFET کانال-N را با نتایج شبیه‌سازی زیرمدار SPICE مقایسه می‌کند.

ایجاد نت‌لیست مشخصه دیود رو به جلو سورس-درین

برای پارامتردهی جدول‌دار دیود رو به جلوی یک MOSFET کانال-N، نت‌لیست SPICE ایجاد کنید که MOSFET در ناحیه خاموش و با بایاس معکوس ولتاژ درین-سورس کار می‌کند. نت‌لیست IAUC100N04S6L014_diode.net مشخصه جریان-ولتاژ دیود رو به جلو را شبیه‌سازی می‌کند.

* دیود رو به جلوی سورس-درین برای MOSFET مدل IAUC100N04S6L014  
.opt DampInductors=0 Thev_Induc=1 Gfarad=0 Gfloat=0 reltol=1e-05 abstol=1e-05 vntol=1e-05 Gmin=0 cshunt=0 cshuntintern=0 gshunt=0 topologycheck=0

X1 dut1 dut2 dut3 dut4 dut5 IAUC100N04S6L014  
V1 dut1 0 pwl(0 0 20 -5)  
V2 dut2 0 -10  
V3 dut3 0 0  
V4 dut4 0 27  
.tran 0.1 20  
.lib IAUC100N04S6L014.cir  
.end

تنظیم پارامترهای جدول داده برای دیود سورس-درین رو به جلو

فایل خام IAUC100N04S6L014_diode1.raw مشخصه‌های دیود رو به جلو شبیه‌سازی‌شده در SPICE را ذخیره می‌کند. برای تنظیم پارامترهای دیود MOSFET، در تب Define Conditions، گزینه Set MOSFET diode parameters را علامت بزنید یا از تابع set_param استفاده کنید.

مقایسه مشخصه‌های دیود رو به جلو

نمودار زیر مشخصه‌های دیود رو به جلوی MOSFET کانال-N را با نتایج شبیه‌سازی زیرمدار SPICE مقایسه می‌کند.

نتایج شبیه‌سازی در زمان واقعی

این مثال روی یک دستگاه هدف بلادرنگ Speedgoat Performance با پردازنده چند هسته‌ای Intel® i7 با فرکانس 3.5 گیگاهرتز تست شده است. این مدل می‌تواند با گام زمانی 200 میکروثانیه در زمان واقعی اجرا شود.